007_resistor_bridge : Resistive Bridge with one arm as sensor
Requires: SmartSpice & Smartview
Minimum Versions: SMARTSPICE 4.6.5.R
The input deck simulates a resistive bridge circuit where one arm is a sensor and .DC and .MEASURE analysis are performed on the circuit. Rubberband the ".param RNOM_SENS" parameter to see effect of changing the resistor and therefore the balance of this bridge-configured circuit.
Input Files
rubberband_example_07.in
* SENSOR BRIDGE
* Rubberband parameters:
* .PARAM RNOM_SENS - sensor output volatage
.OPTION NOMOD
VBIAS 1 0 DC 10
*
* INSTRUMENTATION BRIDGE
*
.PARAM RNOM=1K
.PARAM RNOM_SENS=1K
RB2 1 3 RNOM
RB4 3 0 RNOM
RB1 1 2 RNOM
*
* RESISTIVE SENSOR (VOLTAGE CONTROLLED)
*
XSENSOR 2 0 10 0 V_CONT_R
*
* XSENSOR CONTROL VOLTAGE
*
VCONT 10 0 DC 1.0
RD1 10 0 1G
*
* SUBCIRCUIT FOR VOLTAGE CONTROLLED RESISTOR
* RESISTOR - 1,2 CONTROL - 4,5
*
.SUBCKT V_CONT_R 1 2 4 5
ERES 1 3 VALUE = { I(VSENSE) * RNOM_SENS * V(4,5) }
VSENSE 3 2 DC 0
.ENDS
*
* ANALYSIS
*
.PARAM DC_START=0.5 DC_STOP=1.5
.DC LIN VCONT DC_START DC_STOP 0.01
*
* VIEW RESULTS
*
.SAVE DC Vsensout='v(2)-v(3)'
*
* MEASURES
*
.MEASURE dc Vsensout_min POINT v(2,3) ARG0 = DC_START
.MEASURE dc Vsensout_cent POINT v(2,3) ARG0 = "DC_START+(DC_STOP - DC_START)/2"
.MEASURE dc Vsensout_max POINT v(2,3) ARG0 = DC_STOP
.MEASURE dc Vsensout_width param='Vsensout_max-Vsensout_min'
.END
Graphics
