* OPAMP Summing Amplifier
* Rubberband parameters:
* .PARAM DCGAIN
* .PARAM RES1
* .PARAM RES2
* .PARAM RES3

.PARAM DCGAIN=100k
.PARAM RES1=10K RES2=1 RES3=1

*
* SINEWAVE 4KHZ
V1	1	0	SIN(0V 1VPEAK 4KHZ)
* SQUARE WAVE 100HZ
V2	2	0	PWL(0MS 1V   5MS 1V   5.01MS -1V   10MS -1V)   
* TRIANGLE WAVE 500HZ
V3	3	0	PWL(0MS -1V  1MS 1V  2MS -1V  3MS 1V  4MS -1V 
                          + 5MS 1V 6MS -1V 7MS 1V 8MS -1V 9MS 1V 10MS -1V)   
*
* INPUT Rs
R1	1	10	RES1
R2	2	10	RES2
R3	3	10	RES3
* FEEDBACK R
RF	11	10	10K
*
* OPAMP
XOP	0 10	11	OPAMP1	
*
*
* OPAMP MACRO MODEL, SINGLE-POLE 
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN	1	2	10MEG
* GAIN BW PRODUCT = 10MHZ
* DC GAIN (100K) AND POLE 1 (100HZ)
EGAIN	3 0	1 2	DCGAIN
RP1	3	4	1K
CP1	4	0	1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER	5 0	4 0	1
ROUT	5	6	10
.ENDS
*
* ANALYSIS 
.TRAN 	0.05MS  10MS

*MEASURES 
.param point0=0
.param point1=5m
.param point2=10m


.MEASURE TRAN max_v11 MAX v(11) FROM=point0 TO=point2
.MEASURE TRAN max_v11_1 MAX v(11) FROM=point0 TO=point1
.MEASURE TRAN max_v11_2 MAX v(11) FROM=point1 TO=point2

.MEASURE TRAN PP_V11 PP V(11)
.MEASURE TRAN PP_v11_1 PP V(11) FROM=point0 TO=point1
.MEASURE TRAN PP_v11_2 PP V(11) FROM=point1 TO=point2

.MEASURE TRAN AVG_V11 AVG V(11)
.MEASURE TRAN AVG_v11_1 AVG V(11) FROM=point0 TO=point1
.MEASURE TRAN AVG_v11_2 AVG V(11) FROM=point1 TO=point2


*CURRENTS VIA  DEVICES 
.save i(r1) i(r2) i(r3)
.save tran v(10) v(11)

.end