Low and High Frequency Noise Modeling of
Active and Passive Devices

Part I

Introduction

Noise measurements are becoming an important part of semiconductor device characterization and SPICE modeling. Noise introduced by the transistors used in Microwave systems greatly influence the overall system behavior. The correct modeling of the Noise figure allows design engineers to make more cost effective system design.

Kinds of Noise

The noise being characterized by noise measurements consists of spontaneous fluctuations caused by ordinary phenomena in active semiconductor devices. Three principal types of noise are thermal noise, shot noise and flicker noise (1/f noise). Thermal noise arises from vibrations of conduction electrons and holes due t their finite temperature. Some of the vibrations have spectral content within the frequency bend of design interest and significantly contribute noise to the signals. Shot noise arises from the quantized nature of the current flow. The origin of the flicker noise are varied, but in BJTs it is caused mainly by traps associated with contamination and crystal defects in the emitter-base depletion region. These traps capture and release carriers in a random fashion, and the time constant associated with this process describes a noise signal with energies concentrated at low frequencies.

Thermal Noise

Thermal noise refers to the kinetic energy of a body of particles as a result of its finite temperature. If some particles are charged (ionized), vibrational kinetic energy may be coupled electrically to another device if a suitable transmission path is provided. The power available, i.e. the maximum rate at which energy can be removed from the body, is kTB where k is Boltzmann's constant, T is the absolute temperature and B is the bandwidth of the transmission path.

Shot Noise

Shot noise is caused by the quantized and random nature of the current flow. Current in semiconductor devices is not continuous but quantized, being limited by the smallest unit of charge e. Particles of charge also flow with random spacing. The arrival of one unit of charge at a boundary is independent of when the previous unit arrived or when the succeeding unit will arrive. Statistical analysis of the random occurrence of particle flow yields that the mean square current variations are uniformly distributed in frequency.

Flicker Noise

Flicker noise is a type of noise found in all commonly used semiconductor active devices. Flicker (1/f ) noise dominates low frequency noise in silicon MOSFET devices. Because MOSFET have large flicker noise, the flicker noise sets a lower frequency limit to the level of signal that can be processed by VLSI devices and circuits. A lot of effort has been spent in understanding and reducing the flicker noise in order to improve the performance of VLSI circuits.

Simulation Examples

Circuit simulation programs model all three types of noise sources. The noise model selector nlev can be used to select suitable noise model that a circuit designer believes dominates the MOSFET operation. A typical example of a SPICE input deck that can be used to investigate the noise in a MOSFET device is presented in Table 1. The circuit used is a simple inverter and noise contributions of the NMOS device are plotted over the frequency range of 0.01Hz to 1.3GHz. Notice that nlev=3 models the low frequency flicker noise and high frequency shot noise.

The noise in a Bipolar BJT device is simulated using a simple bias circuit. The SPICE input deck is described in Table 2 and the results are described in Figure 1.

.options numdgt=8 nomod acct
+ defnrd = 1.0 defnrs = 1.0

vdd vdd 0 5v
vin g 0 dc 0 ac 1
mp out g vdd vdd p2 w=5u l=5u
mn out g 0 0 n2 w=5u l=5u
.noise v(out) vin dec 10 0.01 1g 1
.save noiset all
.save noises all

.model n2 nmos ( level = 3 tox = 1.9e-8
+ rs = 1830 rd = 1830 ld = 6e-8
+ wd = 5e-8 nsub = 5.3e16 vto = 0.65
+ uo = 700 delta = 0.8932
+ vmax = 1.5e5 xj = 5.291582e-7 kappa = 0.085
+ eta = 0.025 theta = 0.078 tpg = 1
+ nfs = 2e11 rsh = 55 xw = 0
+ xl = 0 ldif = 2.5e-7 hdif = 1.4e-6
+ del = 0 acm = 2 cj = 3.5e-4
+ pb = 0.85 mj = 0.39 fc = 0.45
+ php = 0.85
+ php = 0.85
+ cjsw = 2.45e-10 mjsw = 0.25 cgso = 3.12e-10
+ cgdo = 3.12e-10 cgbo = 1.8165e-10
* temperature parameters
+ bex=-2.15 tcv=0.0012 trd=0.0025
+ trs=0.0025
+ af = 1.0
+ kf = 1e-19)

.model p2 pmos ( level = 3 tox = 1.9e-8
+ rs = 2000 rd = 2000 ld = 6e-8
+ wd = 2.5e-8 nsub = 3.3e16 vto = -0.85
+ uo = 250 delta = 1.9
+ vmax = 1.58e5 xj = 6e-8 kappa = 1.2
+ eta = 0.037 theta = 0.12 tpg = -1
+ nfs = 1e11 rsh = 90 xw = 0
+ xl = -0.2u ldif = 2.5e-7 hdif = 1.4e-6
+ del = 0 acm = 2 cj = 5.95e-4
+ pb = 0.81 mj = 0.46 fc = 0.45
+ php = 0.81
+ cjsw = 3.7e-10 mjsw = 0.30 cgso = 3.23e-10
+ cgdo = 3.23e-10 cgbo = 0.90825e-10
* temperature parameters
+ bex=-1.47 tcv=-0.0019 trd=0.0011
+ trs=0.0011
+ af = 1.0
+ kf = 1e-19)

.modif loop=3
+ n2(nlev)+=(0)1 p2(nlev)+=(0)1

.end

Table 1. Typical SPICE input deck to simulate noise contribution for a MOSET device.

 

EXAMPLE4: RCA3040 WIDEBAND AMPLIFIER

*
* DC, AC and NOISE STATEMENTS
*
VIN 1 0 DC 0.7 AC 1
Vcc 2 0 dc 5v
Rcc 2 3 1k
Q1 3 1 0 QNL
.MODEL QNL NPN(BF= 80 RB = 100 CCS= 2PF TF= 0.3NS AF=1.0
+ KF=5.4E-16 TR=6NS CJE =3PF CJC =2PF VA = 50 )
*
*.DC VIN -0.25 0.25 0.005
*.AC DEC 10 1 10GHZ
.NOISE V(3) VIN DEC 10 100k 1.3G 1
.save all
*
.OPTIONS ACCT RELTOL=0.001 NOMOD
.END


Table 2. Typical SPICE input deck to simulate noise contribution for a Bipolar device.


 

Figure 1 - Typical Noise Analysis for a Bipolar BJT Device

 

Figure 2. Typical Noise analysis output for a MOSFET device. Notice that Nlev = 3 models the noise contributions most accurately, accounting properly for 1/f noise at low frequencies and f noise at high frequencies.

Measurements

UTMOSTIII supports all the necessary measurement equipment to perform noise figure measurements. The high frequency noise is measured using HP8970 noise figure meter. The low frequency noise is measured using HP3561 or HP3562 spectrum analyzers.

Extreme care should be taken in laying out various components to minimize parasitic noise. Coaxial cables must be used for all critical connections. Isolated probe holders should be used to avoid parasitics and device under test should be properly shielded. Regular DC sources can be used to provided DC bias.

References

[1] "Noise Figure Measurements, Principles and Applications", Hewlett-Packard, April 1988.

[2] Product Note 8970B/S-2, Hewlett-Packard, August 1987.

[3] "Fundamentals of RF and Microwave Noise Figure Measurements", Application Note 57-1, Hewlett-Packard, July 1983.