SmartSpice BSIM3 v3 Non-Quasi Static Model

SMARTSPICE BSIM3 VERSION 3
Non-Quasi Static Model
Application Note

UC Berkeley released the final version of the BSIM3v3 model in October, 1995. This model is now available in SmartSpice 1.4.0 in two different variants . The SmartSpice implementation is referred to as MOSFET Level 8. The original Berkeley model is also available within SmartSpice as MOSFET Level 81. Both models produce virtually identical IDS currents when commonly accepted model parameter sets are used.However, these models are not identical in terms of the Non-Quasi Static Model (NQS) implementation.

This application note describes the SmartSpice BSIM3v3 Non-Quasi Static Model implementation and its verification by the application of two-dimensional device simulation using Silvaco's ATLAS program.

 

  • Section 1 describes the SmartSpice BSIM3v3 NQS model parameters, and primary differences between SmartSpice Level 8 and UC Berkeley Level 81 models
  • Section 2 contains NQS model verification by ATLAS

For further information regarding the BSIM3v3 Level 8 implementation, see Application Notes:

  1. SmartSpice BSIM3 Version 3
  2. SmartSpice BSIM3v3 Intrinsic Capacitance Models

SECTION 1
SmartSpice BSIM3 Version 3

1.1 List of Parameters

The following model parameters are used in the NQS model.

Parameter Description Units Default
NQSMOD Flag for NQS model none 0
XPART Charge partition rate flag none 0.4
ELM Elmore constant of the channel none 5

Note:

The NQSMOD parameter can also be specified as an instance parameter. The instance parameter value overrides the model parameter value. By default the NQS model is OFF. To invoke the NQS model specify NQSMOD=1.

1.2 SmartSpice NQS Model Implementation

The SmartSpice NQS model is based on the UC Berkeley implementation described in "BSIM3v3 Manual (Final Version)", Department of Electrical Engineering and Computer Science, University of California, Berkeley, 1995.However, the Berkeley implementation has a number of mistakes in NQS derivative calculations and the matrix assembly. The SmartSpice implementation corrects these mistakes.

The following example illustrates the difference between Level 8 and Level 81 NQS implementations.

1.3 Example

 


	***Test NQSmod=1 ( P-channel ) Level 81 vs Level 8
	* model from
	* http://rely.eecs.berkeley.edu:8080/bsim3www/bsim3.html
	.OPTIONS GMIN=1e-20
	.OPTIONS RELTOL=1e-8 ABSTOL=1e-18 vntol=1e-7
	+NUMDGT=7 NOMOD

	.TRAN 0.005n 2ns

	Vgg gg 0 DC 1 pulse ( 5v 0 0 0.6n 0.6n 2n 4n)
	Vdd dd 0 DC 0
	Vss ss 0 dc 5
	Vbb bb 0 dc 5

	***** Level 81

	M1 d1 g1 s1 b1 pmos81 W=10.0u L=5.0u AD=1e-30 AS=1e-30
	vd1 dd d1 dc 0
	vg1 gg g1 dc 0
	vs1 ss s1 dc 0
	vb1 bb b1 dc 0

	***** Alias for the M1 Kirchoff current sum
	.LET kir1='i(vg1)+i(vd1)+i(vs1)+i(vb1)'

	***** Level 8

	M2 d2 g2 s2 b2 pmos8 W=10.0u L=5.0u AD=1e-30 AS=1e-30
	vd2 dd d2 dc 0
	vg2 gg g2 dc 0
	vs2 ss s2 dc 0
	vb2 bb b2 dc 0

	***** Alias for the M2 Kirchoff current sum
	.LET kir2='i(vg2)+i(vd2)+i(vs2)+i(vb2)'

	***** Statements to verify that the Kirchoff
	***** current law is satisfied

	.MEASURE max_kir1 MAX 'ABS(kir1)'
	.MEASURE max_i_vd1 MAX 'ABS(i(vd1))'
	.MEASURE error81 EXPR VAL='max_kir1/max_i_vd1'
	.MEASURE max_kir2 MAX 'ABS(kir2)'
	.MEASURE max_i_vd2 MAX 'ABS(i(vd2))'
	.MEASURE error8 EXPR VAL='max_kir2/max_i_vd2'

	***** Berkeley P-channel Level 81 Model

	.MODEL pmos81 pmos LEVEL=81
	+ NQSMOD=1
	+ Tnom=27.0
	+ nch= 5.73068E+16 tox=1.00000E-08 xj=1.00000E-07
	+ lint= 8.195860E-08 wint=-1.821562E-07
	+ vth0= -.86094574 k1= .341038 k2= 2.703463E-02 k3=12.24589
	+ dvt0= .767506 dvt1= .65109418 dvt2=-0.145
	+ nlx= 1.979638E-07 w0=1.1e-6
	+ k3b= -2.4139039
	+ vsat= 60362.05 ua=1.348481E-09 ub= 3.178541E-19 uc=1.1623e-10
	+ rdsw= 498.873 u0= 137.2991 prwb=-1.2e-5
	+ a0= .3276366
	+ keta=-1.8195445E-02 a1= .0232883 a2= .9
	+ voff=-6.623903E-02 nFactor= 1.0408191 cit= 4.994609E-04
	+ cdsc= 1.030797E-3 cdscb=2.84e-4
	+ eta0= .0245072 etab=-1.570303E-03
	+ dsub= .24116711
	+ pclm= 2.6813153 pdiblc1= 4.003703E-02 pdiblc2= .00329051 pdiblcb=-2.e-4
	+ drout= .1380235 pscbe1= 0 pscbe2=1.e-28
	+ pvag= -.16370527 prwg=-0.001 ags=1.2
	+ dvt0w=0.58 dvt1w=5.3e6 dvt2w=-0.0032
	+ kt1=-.3 kt2=-.03 prt=76.4 at= 33000 ute=-1.5
	+ ua1= 4.31E-09 ub1= 7.61E-18 uc1=-2.378e-10
	+ kt1l=0
	+ wr=1 b0=1e-7 b1=1e-7 dwg=5e-8 dwb=2e-8 delta=0.015
	+ cgdl=1e-10 cgsl=1e-10 cgbo=1e-10 xpart=0.4
	+ cgdo=0.4e-9 cgso=0.4e-9
	+ clc=0.1e-6 cle=0.6
	ckappa=0.6

	***** SmartSpice P-channel Level 8 Model.

	MODEL pmos8 pmos LEVEL=8
	+ NQSMOD=1
	+ Tnom=27.0
	+ nch= 5.73068E+16 tox=1.00000E-08 xj=1.00000E-07
	+ lint= 8.195860E-08 wint=-1.821562E-07
	+ vth0= -.86094574 k1= .341038 k2= 2.703463E-02 k3=12.24589
	+ dvt0= .767506 dvt1= .65109418 dvt2=-0.145
	+ nlx= 1.979638E-07 w0=1.1e-6
	+ k3b= -2.4139039
	+ vsat= 60362.05 ua=1.348481E-09 ub= 3.178541E-19 uc=1.1623e-10
	+ rdsw= 498.873 u0= 137.2991 prwb=-1.2e-5
	+ a0= .3276366
	+ keta=-1.8195445E-02 a1= .0232883 a2= .9
	+ voff=-6.623903E-02 nFactor= 1.0408191 cit= 4.994609E-04
	+ cdsc= 1.030797E-3 cdscb=2.84e-4
	+ eta0= .0245072 etab=-1.570303E-03
	+ dsub= .24116711
	+ pclm= 2.6813153 pdiblc1= 4.003703E-02 pdiblc2= .00329051 pdiblcb=-2.e-4
	+ drout= .1380235 pscbe1= 0 pscbe2=1.e-28
	+ pvag= -.16370527 prwg=-0.001 ags=1.2
	+ dvt0w=0.58 dvt1w=5.3e6 dvt2w=-0.0032
	+ kt1=-.3 kt2=-.03 prt=76.4 at= 33000 ute=-1.5
	+ ua1= 4.31E-09 ub1= 7.61E-18 uc1=-2.378e-10
	+ kt1l=0
	+ wr=1 b0=1e-7 b1=1e-7 dwg=5e-8 dwb=2e-8 delta=0.015
	+ cgdl=1e-10 cgsl=1e-10 cgbo=1e-10 xpart=0.4
	+ cgdo=0.4e-9 cgso=0.4e-9
	+ clc=0.1e-6 cle=0.6 ckappa=0.6
	.END
	

Simulation Results

 

	***Test NQSmod=1 ( P-channel ) Level 81 vs Level 8
	Transient Analysis, 27 deg C,Fri Mar 29 10:58:37 1996

	measure max_kir1 max OUT = abs(kir1)
	Ymax = 5.9540157e-04
	Xmax = 4.2280000e-10

	measure max_i_vd1 max OUT = abs(i(vd1))
	Ymax = 5.2071352e-04
	Xmax = 2.0000000e-09 (end of meas. interval)

	measure error81 expr
	VAL = 1.1434340e+00

	measure max_kir2 max OUT = abs(kir2)
	Ymax = 8.0014120e-17
	Xmax = 6.0007332e-10

	measure max_i_vd2 max OUT = abs(i(vd2))
	Ymax = 5.2072375e-04
	Xmax = 2.0000000e-09 (end of meas. interval)

	measure error8 expr
	VAL = 1.5365944e-13
	

These results show that the Kirchoff current law is satisfied in the SmartSpice NQS model ( error8=1.5365944e-13 ). In the Berkeley Level 81 NQS model, the Kirchoff current law is not satisfied in the P-channel transistor in all modes of operation, and in the N-channel transistor when the source voltage is higher than the drain voltage (reverse mode of operation).

 

SECTION 2
Non-Quasi Static Model vs Quasi Static

The following example illustrates how the type of the model affects the transistor current behavior during fast transients.

 

	*****Test NQSmod=0 vs NQSmod=1 ( N-channel )
	* model from* http://rely.eecs.berkeley.edu:8080/bsim3www/bsim3.html
	* TOX = 2.00E-08
	.OPTIONS GMIN=1e-20
	.OPTIONS RELTOL=1e-8 ABSTOL=1e-18 vntol=1e-7
	+NUMDGT=7 NOMOD

	.TRAN 0.005n 3ns

	Vgg gg 0 DC 1 pulse ( 0 5v 0 0.6n 0.6n 1n 4n)
	Vdd dd 0 DC 2v
	Vss ss 0 dc 0
	Vbb bb 0 dc 0

	***** NQSMOD=0
	M1 d1 g1 s1 b1 nmos W=10.0u L=5.0u AD=1e-30 AS=1e-30
	vd1 dd d1 dc 0
	vg1 gg g1 dc 0vs1 ss s1 dc 0
	vb1 bb b1 dc 0

	***** NQSMOD=1
	M2 d2 g2 s2 b2 nmos W=10.0u L=5.0u AD=1e-30 AS=1e-30 NQSMOD=1
	vd2 dd d2 dc 0
	vg2 gg g2 dc 0
	vs2 ss s2 dc 0
	vb2 bb b2 dc 0

	.MEASURE avg_i_vd1 AVG i(vd1)
	.MEASURE avg_i_vd2 AVG i(vd2)

	***** N-channel BSIM3v3 model
	.model nmos nmos level=8
	+ Tnom=27.0
	+ NQSMOD=0 XPART=0.4
	+ nch= 1.024685E+17 tox=2.00000E-08 xj=1.00000E-07
	+ lint= 3.75860E-08 wint=-2.02101528644562E-07
	+ vth0= .6094574 k1= .5341038 k2= 1.703463E-03 k3=-17.24589
	+ dvt0= .1767506 dvt1= .5109418 dvt2=-0.05
	+ nlx= 9.979638E-08 w0=1e-6
	+ k3b= 4.139039
	+ vsat= 97662.05 ua=-1.748481E-09 ub= 3.178541E-18 uc=1.3623e-10
	+ rdsw= 298.873 u0= 307.2991 prwb=-2.24e-4
	+ a0= .4976366
	+ keta=-2.195445E-02 a1= .0332883 a2= .9
	+ voff=-9.623903E-02 nFactor= .8408191 cit= 3.994609E-04
	+ cdsc= 1.130797E-04 cdscb=2.4e-5
	+ eta0= .0145072 etab=-3.870303E-03
	+ dsub= .4116711
	+ pclm= 1.813153 pdiblc1= 2.003703E-02 pdiblc2= .00129051 pdiblcb=-1.034e-3
	+ drout= .4380235 pscbe1= 5.752058E+08 pscbe2= 7.510319E-05
	+ pvag= .6370527 prt=68.7 ngate=1.e20 alpha0=1.e-7 beta0=28.4
	+ prwg=-0.001 ags=1.2
	+ dvt0w=0.58 dvt1w=5.3e6 dvt2w=-0.0032
	+ kt1=-.3 kt2=-.03 at= 33000 ute=-1.5
	+ ua1= 4.31E-09 ub1= 7.61E-18 uc1=-2.378e-10
	+ kt1l=1e-8
	+ wr=1 b0=1e-7 b1=1e-7 dwg=5e-8 dwb=2e-8 delta=0.015
	+ cgdl=1e-10 cgsl=1e-10 cgbo=1e-10
	+ cgdo=0.4e-9 cgso=0.4e-9
	+ clc=0.1e-6 cle=0.6 ckappa=0.6
	.END
	

Simulation Results

The simulation results produced by SmartSpice and ATLAS are shown in Figure 1 and Figure 2 respectively.



Figure 1: BSIM3v3 drain currents for NQSMOD=0 and NQSMOD=1



Figure 2: Drain current simulated by ATLAS.

As shown in Figure 1, the drain current i(vd1) of the transistor M1 with a quasi static model has large spikes durung fast transients. The non-quasistatic model of the transistor M2 takes into account finite channel charge build-up time. The drain current i(vd2) behavior is shown to being much closer agreement to the two dimensional ATLAS results, which self-consistently take into account all the physical device phenomena.

The simulation results are also in good agreement with those in: Mansun Chan, et al, "A Relaxation Time Approach to Model the Non-Quasi Static Transient Effects in MOSFET's", IEDM, 1994 Technical Digest, pp. 169-172, Dec. 1994.